Séance 4 · DAX

Les chiffres que la direction regarde le lundi

Chiffre d'affaires, panier moyen, marge, part du total, évolution sur un an : chaque indicateur de Datashop devient une mesure, écrite une fois et juste dans tous les visuels, quel que soit le filtre. Cette séance écrit ces mesures — et retrouve, au centime, les chiffres de référence de l'entreprise.

⏱️ 1 h 30 🎚️ Avancé 📁 le modèle de la séance 3 🎯 23 exercices corrigés

Ta progression

0% 0 / 6 modules

Quelle licence as-tu ?

Le cours n'affiche que ton chemin, et retient ton choix. Tu ne sais pas ? La séance 1 te montre où la lire.

Point de départ : le modèle Datashop de la séance 3 (six tables, le calendrier, les relations). Tu ne l'as pas ? Recharge datashop-modele.xlsx et refais les relations — dix minutes.

Dans le navigateur : Toutes licences les mesures se créent dans la vue de modèle (Mon espace de travail, … du modèle › Ouvrir le modèle sémantique), ruban Accueil › Nouvelle mesure. Depuis un rapport, Afficher le modèle sémantique y ramène : le rapport en ligne ne crée pas de mesure.

📗 Tu connais Excel ? Les équivalences de cette séance

En DAX	≈ En Excel	L'idée
`SUM()`	`SOMME()`	Additionner une colonne
`CALCULATE(expr, filtre)`	`SOMME.SI.ENS()`	Un calcul avec des critères
`DIVIDE(a, b)`	`SIERREUR(a/b ; 0)`	Une division sans erreur ÷0
`SUMX(table, a*b)`	`SOMMEPROD()`	Calculer ligne par ligne, puis additionner
`RELATED()`	`RECHERCHEX()`	Lire une colonne d'une table reliée

Des analogies, pas des équivalences : une mesure DAX se recalcule selon les filtres de chaque visuel, ce qu'aucune formule Excel ne fait seule.

Colonne calculée ou mesure

La distinction la plus importante du DAX

✓ Terminé›

	Colonne calculée	Mesure
Calculée	Au chargement, ligne par ligne	À l'affichage, selon les filtres du visuel
Stockée	Oui, elle alourdit le modèle	Non, rien n'est stocké
On la place	En axe, en légende, en segment	En valeur
Exemple Datashop	La tranche de prix d'un produit	Le chiffre d'affaires, le taux de marge

On dit que la colonne calculée vit dans un contexte de ligne (elle voit la ligne en cours), et la mesure dans un contexte de filtre (elle voit ce que le visuel, les segments et les filtres ont retenu).

La règle de ce cours : tout ce qui s'additionne, se moyenne, se compte ou se compare est une mesure. Une colonne calculée seulement quand on a besoin de la valeur pour ranger les données (un axe, un segment).

Les premières mesures

SUM, COUNTROWS, DISTINCTCOUNT, DIVIDE

✓ Terminé›

Dans la vue de modèle, sélectionne la table Commandes dans le volet Données : c'est là qu'on range les mesures du cours.
Accueil › Nouvelle mesure, et écris dans la barre de formule :

DAX — Mesures

CA brut = SUM(Commandes[Total_HT])
Nb commandes brut = COUNTROWS(Commandes)
Clients acheteurs = DISTINCTCOUNT(Commandes[ID_Client])
Panier brut = DIVIDE([CA brut], [Nb commandes brut])

Pose chacune dans une carte. Puis mets-les dans une table avec Commandes[Canal] : la même mesure donne un chiffre par canal, sans rien réécrire — c'est le contexte de filtre.

Pourquoi DIVIDE et pas / ? Sur un canal sans commande, [CA] / [Nb] renvoie une erreur qui casse le visuel. DIVIDE renvoie un vide, proprement. Une mesure appelle une autre mesure entre crochets, sans nom de table : [CA brut].

Demande · Camille Roy, directrice générale

« Nos chiffres clés, sur les deux ans »

Donne à Camille le chiffre d'affaires, le nombre de commandes, le nombre de clients acheteurs et le panier moyen — avec ces quatre premières mesures.

🔍 Analyse. Compare ton CA au chiffre de référence de Datashop : 435 900,85 €. Tu ne tombes pas dessus. Ne va pas plus loin avant d'avoir compris pourquoi : un indicateur faux présenté à une directrice générale est pire qu'aucun indicateur.

Voir la solution

À trouver : CA brut 447 484,91 €, 966 commandes, 140 clients acheteurs, panier brut 463,23 €. L'écart avec la référence (11 584,06 €) vient des 30 commandes annulées, comptées ici comme des ventes. Le module suivant les écarte.

🏋️ À toi de jouer — dans Power BI

Ma table Commandes contient les quatre mesures, et chacune est affichée dans une carte.

CALCULATE

Changer les filtres le temps d'un calcul

✓ Terminé›

CALCULATE(expression, filtre1, filtre2…) évalue une expression après avoir ajouté ou remplacé des filtres. C'est la fonction la plus importante du DAX.

DAX — Les mesures de référence

CA facturé = CALCULATE(SUM(Commandes[Total_HT]), Commandes[Statut] <> "Annulée")
Nb commandes = CALCULATE(COUNTROWS(Commandes), Commandes[Statut] <> "Annulée")
Panier moyen = DIVIDE([CA facturé], [Nb commandes])
CA télévente = CALCULATE([CA facturé], Commandes[Canal] = "Téléphone")

Le filtre de CALCULATE remplace celui du visuel sur la même colonne. Dans un tableau par canal, CA télévente affiche 82 086,00 € sur chaque ligne, y compris « Magasin » : le filtre Canal = "Téléphone" a écrasé celui de la ligne. C'est parfois voulu, parfois une erreur : il faut le savoir.

Demande · Camille Roy, suite

« Les vrais chiffres, cette fois »

Écris les trois mesures de référence et donne à nouveau le CA, le nombre de commandes et le panier moyen.

🔍 Analyse. Les trois chiffres doivent tomber au centime sur ceux que publie le contrôle de gestion. Si c'est le cas, ton modèle est « réconcilié » — c'est le mot qu'on emploie en entreprise, et c'est la condition pour qu'on te fasse confiance sur tout le reste.

Voir la solution

À trouver : CA facturé 435 900,85 €, 936 commandes, panier moyen 465,71 € — les chiffres de référence de Datashop. Par canal : site web 160 835,80 €, magasins 134 865,29 €, téléphone 82 086,00 €, marketplace 58 113,76 €.

🏋️ À toi de jouer — dans Power BI

Mes mesures CA facturé, Nb commandes et Panier moyen tombent sur les chiffres de référence. J'ai observé CA télévente dans un tableau par canal, et compris pourquoi il se répète.

SUMX, RELATED et la marge

Calculer ligne par ligne, puis additionner

✓ Terminé›

Le coût d'une ligne vendue, c'est sa quantité multipliée par le coût d'achat du produit — qui est dans une autre table. SUMX parcourt les lignes une à une, RELATED va lire la colonne de la table reliée, côté « 1 ».

DAX — La marge

CA produits = CALCULATE(SUM(Lignes_commande[Total_ligne_HT]), Commandes[Statut] <> "Annulée")

Coût d'achat =
CALCULATE(
    SUMX(Lignes_commande, Lignes_commande[Quantité] * RELATED(Produits[Coût_achat_HT])),
    Commandes[Statut] <> "Annulée"
)

Marge = [CA produits] - [Coût d'achat]
Taux de marge = DIVIDE([Marge], [CA produits])

Passe Taux de marge au format pourcentage (Outils de mesure › Format › Pourcentage, une décimale).

Le piège de la moyenne des taux. Dans une matrice par catégorie, la ligne de total du taux de marge n'est pas la moyenne des sept taux affichés : la mesure recalcule Marge ÷ CA sur tout le périmètre. Heureusement : la moyenne simple des taux donne 48,6 %, alors que Datashop marge en réalité à 45,6 % — les Écrans, qui pèsent lourd, tirent le vrai taux vers le bas.

Demande · Direction commerciale

« Où gagnons-nous vraiment de l'argent ? »

Construis une matrice : Produits[Catégorie] en lignes, CA produits, Marge et Taux de marge en valeurs. Trie par CA.

🔍 Analyse. La catégorie qui fait le plus de chiffre d'affaires a la pire marge ; celle qui en fait le moins a la meilleure. Formule la conclusion pour la direction en une phrase, sans jargon — puis propose une action commerciale qui en découle.

Voir la solution

À trouver : CA produits 435 184,05 €, coût 236 840,00 €, marge 198 344,05 €, taux 45,6 %. Écrans : 113 638,28 € de CA, le premier, mais 38,8 % de marge, la plus faible. Services : 27 381,70 €, mais 69,3 %. Vendre beaucoup n'est pas gagner beaucoup : proposer systématiquement l'installation ou la garantie avec chaque écran relève la marge du panier.

🏋️ À toi de jouer — dans Power BI

Ma matrice par catégorie affiche CA, marge et taux, et son total tombe sur 45,6 %.

Des mesures qu'on peut relire

Nommer, formater, ranger, commenter

✓ Terminé›

Des noms en français, sans abréviation obscure : CA facturé plutôt que Mesure 3. Le nom s'affiche dans les visuels.
Des mesures explicites : plutôt que de glisser la colonne Total_HT (somme implicite), on glisse la mesure CA facturé. Une seule définition du CA dans tout le rapport.
Un format à la mesure : devise, pourcentage, décimales.
Des dossiers d'affichage (volet Propriétés de la mesure) : « Ventes », « Marge », « Temps ».
Un commentaire quand la règle de gestion n'est pas évidente : // les commandes annulées ne sont pas du CA.

Une seule définition par indicateur. Si deux mesures « CA » coexistent — l'une avec les annulées, l'autre sans —, deux pages du rapport afficheront deux chiffres différents. La réunion sera consacrée à savoir lequel est juste, pas à décider.

✓

Quiz de fin de séance

Six questions pour vérifier que c'est acquis

✓ Terminé›

Six questions de DAX, dont deux à écrire.

Les mesures sont prêtes. La séance 5 les met en page : choisir le bon visuel, construire la page de pilotage, et surtout dire ce qu'elle montre.

STOP exercices. Tu as lu tout l'onglet et répondu à ses questions : arrête-toi ici, ne passe pas encore à l'onglet suivant. En cours, ton intervenant montre l'essentiel sur son écran, puis vous refaites ensemble :

La marge par catégorie, et le dépôt — atelier 2 : les six contrôles, déposé, mail envoyé
Les mesures de l'atelier 3 — atelier 3 : les cinq mesures prêtes

Tu travailles seul ? Fais ces exercices maintenant, sur ton modèle sur datashop-modele.xlsx (page Ateliers), puis passe à l'onglet suivant.